Submission #22756

---

Source Code Expand

module main;

import std.algorithm; // この解答で使った項目: sort
import std.stdio; // この解答で使った項目: readln, writefln
import std.conv; // この解答で使った項目: to
import std.string; // この解答で使った項目: strip

void main()
{
    // キー の型が char (文字), 値の型が int (整数) の連想配列を定義
    int[char] answers;
    // char 型の変数 letter に 文字列 "1234" の要素 (文字 '1', '2', '3', '4') を順に割り当てるループ
    foreach (char letter; "1234")
    {
        // 正答の出現回数を 0 に初期化
        answers[letter] = 0;
    }

    // std.stdio.readln: 標準入力1行を読む (行末文字は残される)
    // std.string.strip: 前後の空白を削る (ここでは行末文字を削る)
    // std.conv.to: 文字列を int へ変換
    auto N = readln().strip().to!int();
    // 一応は入力としておくが、実は問題を解くのには使わない。

    string input = readln().strip();
    foreach (char letter; input)
    {
        // 正答の出現回数を数える
        answers[letter] += 1;
    }
    debug // デバッグの時に実行されるコード。試しにそれぞれの文字が正答になった回数を出力してみる。
    {
        // 連想配列にわたってループする。順番は連想配列の中で任意に決められてしまうので、1 から順番になるわけではない。
        foreach (char letter, int count; answers)
        {
            // std.writefln: 出力の形式を指定して出力する。
            // - "%c" に対応する char 型の変数に入っている文字を出力。
            // - "%d" に対応する整数 (int など) 型の変数に入っている数を文字列として出力。
            writefln("%c occurs %d time(s).", letter, count);
        }

        // 順番を決めたかったら キー を好きな順番に並べておいて、その順にループして連想配列へアクセスすればよい。
        foreach (char letter; "1234")
        {
            writefln("%c occurs %d time(s).", letter, answers[letter]);
        }
    } // コメントアウトなどしなくても、Submit すれば debug 部分は実行されない。

    // 連想配列 values プロパティ: 値のみを取り出す。
    // std.algorithm.sort: 配列を直接変更によって並び変え、しかも返す。
    // - 並び変える前のものに名前がついているなら、sort したら元の名前で使えばよい。
    // - 今は answers から取得した values を並び変えているので、返ってきた結果を変数に代入して使う。
    // - 型の名前は難しい (SortedRange!(なんとかかんとか)) ので auto にしておこう。
    // 各正答の出現回数を並び変える。小さいものから大きいものへ。
    auto counts = answers.values.sort();
    writefln("%d %d", counts[3], counts[0]);
}

// simple version: http://arc001.contest.atcoder.jp/submissions/22753

Submission Info

Judge Result